unit WinExc32;
// Author    : Francis Parlant.
// Update    : Bill Rinko-Gay
// Parameters:
//    Path: a null terminated string with the command line
//    Visibility: Windows SHOW constant such as WS_RESTORE
//    Timeout: DWORD time in miliseconds or INFINITE to wait forever 
//
// The previous version went into a loop, constantly checking to see
// if the exec'ed program had terminated.  This version uses the Win95
// API call to WaitForSingleObject to block processing until the
// exec'ed program has terminated.  The return value will be either
// an error code from the CreateProcess function, or the result
// of the wait.

interface

uses Windows;

function WinExecAndWait32(Path: PChar; Visibility: Word;
  Timeout : DWORD): integer;

implementation

function WinExecAndWait32(Path: PChar; Visibility: Word;
  Timeout : DWORD): integer;
var
  WaitResult : integer;
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
  iResult : integer;
begin
  FillChar(StartupInfo, SizeOf(TStartupInfo), 0);
  with StartupInfo do
  begin
    cb := SizeOf(TStartupInfo);
    dwFlags := STARTF_USESHOWWINDOW or STARTF_FORCEONFEEDBACK;
	{ you could pass sw_show or sw_hide as parameter: }
    wShowWindow := visibility;
  end;
  if CreateProcess(nil,path,nil, nil, False,
		NORMAL_PRIORITY_CLASS, nil, nil,
		StartupInfo, ProcessInfo) then
  begin
    WaitResult := WaitForSingleObject(ProcessInfo.hProcess, timeout);
    { timeout is in miliseconds or INFINITE if
	  you want to wait forever }
    result := WaitResult;
  end
  else
  { error occurs during CreateProcess see help for details }
    result:=GetLastError;
end;

end.